-- G. Kemnitz: Technische Informatik 
-- Band 2: Entwurf digitaler Schaltungen
-- 4.2.1 Zeitdiskrete Simulation
--
-- zeitdiskrete Simulationsmodell eines Inverters
----------------------------------------------------------------


use work.PhySim_pack.all;

entity Inverter is
generic (
  U_init: tSpannung:=0.0;
  UV: tSpannung:=5.0;     -- Versorgungsspannung in V
  UTN: tSpannung:=1.0;    -- Einschaltspannung des NMOS-Transistors in V
  UTP: tSpannung:=-1.0;   -- Einschaltspannung des PMOS-Transistors in V
  beta_N:tBeta:= 1.0E-3;  -- Leitfähigkeitsfaktor NMOS-Transistor in A pro V^2
  beta_P:tBeta:=-1.0E-3;  -- Leitfähigkeitsfaktor NMOS-Transistor in A pro V^2
  CL:tKapazitaet:=3.0E-14; -- Kapazitaet in Farad
  dt:delay_length:=2 ps);-- Zeitschrittweite
 port(ux: in tSpannung;
  uy: out tSpannung);
end entity;

architecture PhySim of Inverter is
begin
 process
  variable vuy:tSpannung:= U_init;
  variable iDN, iDP: tStrom;
  constant u_eps: tSpannung:=1.0E-3;
 begin
  uy <= vuy; 
  wait for dt;
  iDP:=ID_PMOS(ux-UV, vuy-UV, UTP, beta_P); 
  iDN:=ID_NMOS(ux, vuy, UTN, beta_N); 

  vuy:=vuy-tSpannung(real(iDP+iDN)*real(dt/fs)*1.0E-15/real(CL));


 end process;
end architecture;